PapaTutuWawa/nixos-config
1
0
Fork 0
Code Issues Pull Requests Projects Releases Wiki Activity

hosts: Move host configuration into its own directory

Browse Source
This commit is contained in:
PapaTutuWawa
2021-08-04 19:17:15 +02:00
parent 97c6fece4c
commit a531a27be5
5 changed files with 101 additions and 23 deletions
Download Patch File Download Diff File Expand all files Collapse all files

101
hosts/ayame.nix Normal file
View File

@@ -0,0 +1,101 @@
{ config, pkgs, modulesPath, lib, ... }:
let
customPkgs = import ../packages/overlay.nix;
unstable = (import ../modules/unstable.nix config);
in {
imports = [
../generic.nix
../modules/hardware/generic.nix ../modules/hardware/bluetooth.nix ../modules/hardware/wifi.nix ../modules/hardware/video.nix ../modules/hardware/mobile.nix
../modules/fonts.nix
../modules/users
../modules/users/alexander.nix
../modules/programs/zsh ../modules/programs/mpv ../modules/programs/git ../modules/programs/tmux ../modules/programs/firefox ../modules/programs/gnome-terminal ../modules/programs/gnome ../modules/programs/nonvm
../modules/programs/distributed-build/offload.nix
];
nixpkgs.overlays = [
customPkgs
];
nixpkgs.config.packageOverrides = pkgs: {
nur = (import ../modules/nur.nix pkgs);
unstable = unstable;
};
environment = {
systemPackages = with pkgs; [
unstable.firmwareLinuxNonfree
sof-firmware
];
};
# Disable dhcpcd as NetworkManager will do it for us
networking = {
interfaces.wlan0.useDHCP = false;
hostName = "ayame";
};
boot = {
loader = {
efi.canTouchEfiVariables = false;
grub = {
enable = true;
efiInstallAsRemovable = true;
device = "nodev";
efiSupport = true;
# The UEFI is pretty wonky
forcei686 = true;
};
};
extraModprobeConfig = "";
initrd = {
availableKernelModules = [ "xhci_pci" "usbhid" "usb_storage" "sd_mod" "sdhci_acpi" ];
kernelModules = [
"kvm-intel" "i915"
];
};
# This spams the console and takes up so much CPU time
kernelParams = [ "modprobe.blacklist=arizona_spi" ];
kernelModules = [];
extraModulePackages = [];
kernelPackages = pkgs.linuxPackages_zen;
};
hardware = {
opengl = {
extraPackages = with pkgs; [ vaapiIntel intel-media-driver ];
};
};
services = {
xserver.videoDrivers = [ "modesetting" "fbdev" ];
};
#systemd.services = {
# rfkill-workaround = {
# enable = true;
# description = "Work around rfkill having the Wifi blocked at boot";
# before = [ "network.target" ];
# wantedBy = [ "multi-user.target" ];
# serviceConfig = {
# Type = "oneshot";
# ExecStart = "rfkill unblock all";
# };
# };
#};
fileSystems = {
"/" = {
device = "/dev/disk/by-label/root";
fsType = "btrfs";
};
"/boot" = {
device = "/dev/disk/by-label/boot";
fsType = "vfat";
};
};
swapDevices = [
{ device = "/dev/disk/by-uuid/cf3b1e1c-c245-4452-ad49-68ac72369e77"; }
];
}

77
hosts/generic.nix Normal file
View File

@@ -0,0 +1,77 @@
{ config, lib, pkgs, python3Packages, ... }:
let
home-manager = builtins.fetchGit {
url = "https://github.com/nix-community/home-manager.git";
rev = "35a24648d155843a4d162de98c17b1afd5db51e4";
ref = "release-21.05";
};
in
{
# Install home-manager
imports = [
"${home-manager}/nixos"
../modules/users # For system.singleUser
];
home-manager.useGlobalPkgs = true;
time.timeZone = "Europe/Berlin";
networking = {
useDHCP = false; # Done by the network manager
networkmanager.enable = false;
};
i18n.defaultLocale = "en_GB.UTF-8";
console = {
font = "Lat2-Terminus16";
keyMap = "de";
};
users = {
mutableUsers = false;
extraUsers = {
root = {
# Disable root login
hashedPassword = "*";
};
# Users configured in vm.nix, nishimiya.nix or miku.nix
};
};
environment = {
systemPackages = with pkgs; [
htop
firejail
vim
git # Otherwise we cannot install home-manager
git-crypt
gnupg
python3
];
};
# We don't tolerate non-free software, except for Steam and Linux firmware
nixpkgs.config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [ "firmwareLinuxNonfree" ];
services = {
connman = {
enable = true;
extraFlags = [ "--nodnsproxy" ];
};
# TODO: Is this correct? Maybe run once
timesyncd.enable = false;
printing.enable = lib.mkDefault false;
avahi.enable = false;
};
security.sudo.extraConfig = ''
Defaults env_keep += "NIXOS_CONFIG"
'';
system.stateVersion = "21.05";
}

78
hosts/isla.nix Normal file
View File

@@ -0,0 +1,78 @@
{ config, pkgs, modulesPath, lib, ... }:
let
unstable = (import ../modules/unstable.nix config);
customPkgs = import ../packages/overlay.nix;
in {
imports = [
../generic.nix
../modules/hardware/generic.nix ../modules/hardware/video.nix
../modules/users/fuck-xi.nix
../modules/programs/zsh ../modules/programs/tmux ../modules/programs/emacs ../modules/programs/firefox ../modules/programs/gnome-terminal ../modules/programs/gnome
];
nixpkgs.overlays = [
(import (builtins.fetchGit {
url = "https://github.com/nix-community/emacs-overlay.git";
ref = "master";
rev = "ce0e9482d53d69bedc8416d8a984d00e17607826";
}))
customPkgs
];
nixpkgs.config.packageOverrides = pkgs: {
nur = (import ../modules/nur.nix pkgs);
unstable = unstable;
};
environment = {
systemPackages = with pkgs; [
emacsPgtkGcc
];
sessionVariables = {
# Prevent us from having to always type it out
#NIXOS_CONFIG = "\${HOME}/Development/Personal/nixos-config/hosts/isla.nix";
};
};
networking = {
interfaces.enp6s0.useDHCP = false;
hostName = "isla";
# Nix otherwise has a conflict with this option
wireless.enable = lib.mkForce false;
# Allow scream to connect to this host
firewall.allowedUDPPorts = [ 4010 ];
};
boot = {
loader = {
systemd-boot.enable = true;
efi.canTouchEfiVariables = true;
};
extraModprobeConfig = "";
initrd = {
availableKernelModules = [ "xhci_pci" "ahci" "usbhid" "sd_mod" "amdgpu" "vendor-reset" ];
kernelModules = [];
};
kernelParams = [];
kernelModules = [];
extraModulePackages = [];
kernelPackages = pkgs.linuxPackages_zen;
};
services = {
emacs.package = pkgs.emacsPgtkGcc;
};
systemd.services.NetworkManager-wait-online.enable = false;
fileSystems = {
"/" = {
device = "/dev/disk/by-label/root";
fsType = "btrfs";
};
};
swapDevices = [ ];
}

165
hosts/miku.nix Normal file
View File

@@ -0,0 +1,165 @@
{ config, pkgs, modulesPath, lib, ... }:
let
unstable = (import ../modules/unstable.nix config);
customPkgs = import ../packages/overlay.nix;
gamemode = pkgs.callPackage ../packages/gamemode {};
in {
imports = [
../generic.nix
../modules/hardware/generic.nix ../modules/hardware/video.nix
../modules/fonts.nix
../modules/users/alexander.nix
../modules/programs/zsh ../modules/programs/git ../modules/programs/mpv ../modules/programs/tmux ../modules/programs/emacs ../modules/programs/firefox ../modules/programs/gnome-terminal ../modules/programs/gnome ../modules/programs/i18n.nix ../modules/programs/gamemode ../modules/programs/nonvm
../modules/programs/distributed-build/builder.nix
#./modules/programs/music
];
nixpkgs.overlays = [
(import (builtins.fetchGit {
url = "https://github.com/nix-community/emacs-overlay.git";
ref = "master";
rev = "ce0e9482d53d69bedc8416d8a984d00e17607826";
}))
customPkgs
];
nixpkgs.config.packageOverrides = pkgs: {
nur = (import ../modules/nur.nix pkgs);
unstable = unstable;
};
environment = {
systemPackages = with pkgs; [
emacsPgtkGcc
unstable.firmwareLinuxNonfree
gajim
libvirt virt-manager qemu
gamemode # Custom package
key-mapper # Custom package
scream
linuxPackages_zen.vendor-reset
];
sessionVariables = {
# Prevent us from having to always type it out
#NIXOS_CONFIG = "\${HOME}/Development/Personal/nixos-config/hosts/miku.nix";
};
};
networking = {
interfaces.enp6s0.useDHCP = false;
hostName = "miku";
# Nix otherwise has a conflict with this option
wireless.enable = lib.mkForce false;
# Allow scream to connect to this host
firewall.allowedUDPPorts = [ 4010 ];
};
boot = {
loader = {
systemd-boot.enable = true;
efi.canTouchEfiVariables = true;
};
extraModprobeConfig = ''
options kvm_amd nested=1
options vfio-pci ids=1002:67df,1002:aaf0
'';
initrd = {
availableKernelModules = [ "xhci_pci" "ahci" "usbhid" "sd_mod" "amdgpu" "vendor-reset" ];
kernelModules = [
"amdgpu" # GPU (duh)
"kvm-amd" "vfio_virqfd" "vfio_pci" "vfio_iommu_type1" "vfio" # Virt
"uinput" # key-mapper
"vendor-reset"
];
};
kernelParams = [
"amd_iommu=on"
"iommu=pt"
"sysrq_always_enabled=1"
"kvm.ignore_msrs=1"
"kvm.report_ignored_msrs=N"
"fbcon=rotate:1"
"quiet"
];
kernelModules = [];
extraModulePackages = [ pkgs.linuxPackages_zen.vendor-reset ];
kernelPackages = pkgs.linuxPackages_zen;
};
services = {
# NOTE: key-mapper has a dbus policy file that we need to include
dbus.packages = [ pkgs.key-mapper ];
emacs.package = pkgs.emacsPgtkGcc;
flatpak.enable = true;
xserver.videoDrivers = [ "amdgpu" ];
udev.extraRules = ''
KERNEL=="uinput", GROUP="input"
'';
sshd.enable = true;
};
virtualisation.libvirtd = {
enable = true;
qemuOvmf = true;
qemuRunAsRoot = false;
qemuVerbatimConfig = ''
user = "alexander"
cgroup_device_acl = [
"/dev/null", "/dev/zero", "/dev/full",
"/dev/random", "/dev/kvm", "/dev/kqemu",
"/dev/rtc", "/dev/hpet", "dev/ptmx",
"/dev/input/by-id/usb-Logitech_G700s_Rechargeable_Gaming_Mouse_93DF48160007-event-mouse",
"/dev/input/by-id/usb-Razer_Razer_BlackWidow_Ultimate-event-kbd",
"/dev/input/by-id/usb-Razer_Razer_BlackWidow_Ultimate-if01-event-kbd",
"/dev/input/by-id/usb-Razer_Razer_BlackWidow_Ultimate-if02-event-mouse",
"/dev/input/by-id/usb-Razer_Razer_BlackWidow_Ultimate-event-if01"
]
'';
};
systemd = {
services.NetworkManager-wait-online.enable = false;
user.services = {
scream = {
enable = false; # Started by the passthrough script
description = "Audio receiver for the Scream virtual network sound card";
wantedBy = [ "multi-user.target" ];
serviceConfig = {
Type = "simple";
ExecStart = "${pkgs.scream}/bin/scream -i virbr0 -o pulse";
RestartAlways = "always";
};
};
gamemode = {
enable = true;
description = "A daemon/lib combo for Linux that allows games to request a set of optimisations be temporarily applied to the host OS.";
wantedBy = [ "multi-user.target" ];
serviceConfig = {
Type = "simple";
ExecStart = "${gamemode}/bin/gamemoded";
Restart = "always";
};
};
};
};
fileSystems = {
"/" = {
device = "/dev/disk/by-label/root";
fsType = "btrfs";
};
"/boot" = {
device = "/dev/disk/by-label/boot";
fsType = "vfat";
};
"/mnt/Storage" = {
device = "/dev/disk/by-label/storage";
fsType = "ext4";
};
};
swapDevices = [ ];
}