nixos-config/overlays/phosh.nix

final: prev:

rec {
  phoc = prev.phoc.overrideAttrs (old: rec {
    version = "0.20.0";

    src = prev.fetchFromGitLab {
      domain = "gitlab.gnome.org";
      group = "World";
      owner = "Phosh";
      repo = "phoc";
      rev = "v${version}";
      sha256 = "1mm47n5x7kjgrpxbvb0d0yvpxgzyg90mmmafb6fxhsqklf2dhryy";
    };

    buildInputs = (map
      (x: if (prev.lib.getName x) == "wlroots"
          then prev.wlroots_0_15
          else x
      ) old.buildInputs);
  });

  phosh = prev.phosh.overrideAttrs (old: rec {
    version = "0.20.0_beta2";
    src = prev.fetchFromGitLab {
      domain = "gitlab.gnome.org";
      group = "World";
      owner = "Phosh";
      repo = "phosh";
      rev = "v${version}";
      fetchSubmodules = true; # including gvc and libcall-ui which are designated as subprojects
      sha256 = "sha256-UzOv6ztxYYE4CIzCYKSRfpZzE7oSEKenVX+umkEmFRw=";
    };

    buildInputs = (map
      (x: if (prev.lib.getName x) == "phoc"
          then phoc
          else x
      ) old.buildInputs);
    
  postFixup = ''
    mkdir -p $out/share/wayland-sessions
    ln -s $out/share/applications/sm.puri.Phosh.desktop $out/share/wayland-sessions/
  '';
  });
}