nixos-config/overlays/simple.nix

final: prev:

{
  gajim = prev.gajim.overrideAttrs (old: {
    # Enable notification sounds
    propagatedBuildInputs = old.propagatedBuildInputs ++ [ prev.gsound ];
  });

  animedl = prev.animedl.overrideAttrs (old: {
    extraPkgs = pkgs: with final; [ mpv ];
  });

  lutris-free = prev.lutris-free.override {
    extraPkgs = ps: with ps; [ openssl ];
  };
  
  retroarch = prev.retroarch.override (old: {
    cores = with prev.libretro; [
      desmume
      sameboy
      mgba
      mupen64plus
      parallel-n64
    ];
  });

  libvirt = prev.libvirt.override {
    # NOTE: This to prevent libvirt from using iptables and loading
    #       ip_tables and the likes
    iptables = prev.iptables-nftables-compat;
  };

  nwg-launchers = prev.nwg-launchers.overrideAttrs (old: rec {
    version = "0.6.3";

    src = prev.fetchFromGitHub {
      owner = "nwg-piotr";
      repo = "nwg-launchers";
      rev = "v${version}";
      sha256 = "05aih05z5dybbv67qjmn90yjrk1k2l0v83hhglqqdin18k5xhq21";
    };
  });

  myxer = prev.myxer.overrideAttrs (old: {
    cargoPatches = [ ../patches/myxer/0000-1.2.1-set-gio-version.patch ];
  });

  xournalpp-git = prev.xournalpp.overrideAttrs (old: {
    version = "1.1.1";
    src = prev.fetchFromGitHub {
      owner = "bhennion";
      repo = "xournalpp";
      rev = "5d1545b0c4303e45b4ddf4ef8a1565eba822a9af";
      sha256 = "1d17lvydlny9pvaxa9xy53wxs7i6d563lp5r9g3r1xpgnb7zli8v";
    };
  });

  discord = prev.discord.overrideAttrs (old: rec {
    version = "0.0.18";
    src = prev.fetchurl {
      url = "https://dl.discordapp.net/apps/linux/${version}/discord-${version}.tar.gz";
      sha256 = "sha256-BBc4n6Q3xuBE13JS3gz/6EcwdOWW57NLp2saOlwOgMI=";
    };
  });

  tor-browser-bundle-bin = prev.tor-browser-bundle-bin.override {
    useHardenedMalloc = false;
  };

  discord-app = prev.discord-app.override { chromium = prev.ungoogled-chromium; };

  lapce = prev.lapce.overrideAttrs (old: rec {
    version = "0.1.2";
    src = prev.fetchFromGitHub {
      owner = "lapce";
      repo = "lapce";
      rev = "v${version}";
      sha256 = "1pn3ikh72z5y1ywx3bilghrzrwqc1inds2yxnz37l8s1azf3nzlc";
    };

    cargoDeps = old.cargoDeps.overrideAttrs (_: {
      inherit src;
      outputHash = "sha256-spmRgwTh0Sg+OvT/s85xEvOfs2DdCihnX6Ya+sDyePM=";
    });
    nativeBuildInputs = with prev; old.nativeBuildInputs ++ [
      wrapGAppsHook
    ];
    buildInputs = with prev; old.buildInputs ++ [
      libglvnd
      glib cairo pango atk gdk-pixbuf gtk3
    ];

    preFixup = ''
      patchelf \
        --add-needed ${prev.vulkan-loader}/lib/libvulkan.so.1 \
        --add-needed ${prev.libglvnd}/lib/libGL.so.1 \
        $out/bin/lapce
    '';
  });

  # See https://github.com/NixOS/nixpkgs/issues/171320
  # Fixes XWayland crashing after a resume.
  xwayland = prev.xwayland.overrideAttrs (old: rec {
    version = "21.1.4";
    src = prev.fetchurl {
      url = "mirror://xorg/individual/xserver/xwayland-${version}.tar.xz";
      sha256 = "sha256-GfZ5XzHPqOs1Kx5bPDefIu5gIOmHAf8sxnnajE8RWfc=";
    };
  });

  # See
  # https://github.com/NixOS/nixpkgs/commit/2bf8d8c0162507d08f9fc48e36ce7225f4879bd4
  libsForQt5 = prev.libsForQt5.overrideScope' (finalp: prevp: {
    plasma5 = prevp.plasma5.overrideScope' (finalq: prevq: {
      plasma-mobile = prevq.plasma-mobile.overrideAttrs (old: {
        buildInputs = with prevp; old.buildInputs ++ [
          plasma-workspace
        ];
      });
    });
  });
  plasma5Packages = prev.plasma5Packages.overrideScope' (finalp: prevp: {
    plasma5 = prevp.plasma5.overrideScope' (finalq: prevq: {
      plasma-mobile = prevq.plasma-mobile.overrideAttrs (old: {
        buildInputs = with prevp; old.buildInputs ++ [
          plasma-workspace
        ];
      });
    });
  });
}