nixos-config/modules/programs/mpv/default.nix

{ config, lib, pkgs, ... }:

let
  makeMpvProfile = { shader, additional ? {} }: {
    glsl-shaders = "${pkgs.anime4k}/usr/share/shaders/${shader}";
    scale = "ewa_lanczossharp";
    cscale = "ewa_lanczossharp";
    gpu-context = "wayland";
    gpu-api = "opengl";
    hwdec = "vaapi";
    vo = "gpu";
    video-sync = "display-resample";
    interpolation = "";
    tscale = "oversample";
  } // additional // (if config.programs.mpv != "" then {
    # Make mpv pop up on the primary screen
    screen-name = config.programs.mpv.primaryScreen;
    fs-screen-name = config.programs.mpv.primaryScreen;
  } else {});
in {
  options.programs.mpv = {
    primaryScreen = lib.mkOption {
      type = lib.types.str;
      default = "";
      description = "The name of the screen to use for fullscreen";
    };
  };
  
  config = {
    environment.systemPackages = with pkgs; [ mpv ];

    home-manager.users."${config.system.singleUser}" = {
      programs.mpv = {
        enable = true;
        config = {
          script-opts = "try_ytdl_first=no";
        };
        defaultProfiles = [ "anime" ];
        profiles = {
          anime = (makeMpvProfile {
            shader = "Anime4K_Upscale_Denoise_CNN_x2_VL.glsl";
            additional = {
              fullscreen = "";
            };
          });
          "anime-denoise" = (makeMpvProfile {
            shader = "Anime4K_Upscale_Denoise_CNN_x2_VL.glsl";
          });
        };
      };
    };
  };
}