final: prev:

let
  # NOTE: For some reason --fs-screen-name and --screen-name are not in
  #       0.33.1. So wait and then remove this.
  mpv-git = prev.mpv-unwrapped.overrideAttrs (old: {
    version = "0.34.0";
    src = builtins.fetchGit {
      url = "https://github.com/mpv-player/mpv.git";
      ref = "master";
      rev = "0b56e1c00a57fdb767674462c299a5c973a9e373";
    };
    patches = [];
  });
in {
  mpv = prev.wrapMpv mpv-git {
    # Prevent the need for prefixing mpv with DRI_PRIME=1
    extraMakeWrapperArgs = [
      "--set" "DRI_PRIME" "1"
    ];
  }; 

  gajim = prev.gajim.overrideAttrs (old: {
    # Enable notification sounds
    propagatedBuildInputs = old.propagatedBuildInputs ++ [ prev.gsound ];
  });

  animedl = prev.animedl.overrideAttrs (old: {
    extraPkgs = pkgs: with final; [ mpv ];
  });

  retroarch = prev.retroarch.override (old: {
    cores = with prev.libretro; [
      desmume
      sameboy
      mgba
      mupen64plus
      parallel-n64
    ];
  });

  libvirt = prev.libvirt.override {
    # NOTE: This to prevent libvirt from using iptables and loading
    #       ip_tables and the likes
    iptables = prev.iptables-nftables-compat;
  };

  nwg-launchers = prev.nwg-launchers.overrideAttrs (old: rec {
    version = "0.6.3";

    src = prev.fetchFromGitHub {
      owner = "nwg-piotr";
      repo = "nwg-launchers";
      rev = "v${version}";
      sha256 = "05aih05z5dybbv67qjmn90yjrk1k2l0v83hhglqqdin18k5xhq21";
    };
  });

  phosh = prev.unstable.phosh.overrideAttrs (old: rec {
    patches = [
     #(prev.fetchpatch {
     #  name = "904-allow-non-numeric-passwords-in-lockscreen.patch";
     #  url = "https://gitlab.gnome.org/World/Phosh/phosh/-/merge_requests/904.patch";
     #  sha256 = "0w349cwfcp9a7hg137l7q45626sggl441mwnf0rx6rwjgn1kd48d";
     #})
      (prev.fetchpatch {
        name = "923-allow-non-numeric-passwords-in-lockscreen.patch";
        url = "https://gitlab.gnome.org/World/Phosh/phosh/-/merge_requests/923.diff";
        sha256 = "168rmcwmyvyhb8xrlrrp3na44h0mda3dkk8iswak6jr2pvxdb30z";
      })
    ];
  });
}