final: prev:

let
  # NOTE: For some reason --fs-screen-name and --screen-name are not in
  #       0.33.1. So wait and then remove this.
  mpv-git = prev.mpv-unwrapped.overrideAttrs (old: {
    version = "0.34.0";
    src = builtins.fetchGit {
      url = "https://github.com/mpv-player/mpv.git";
      ref = "master";
      rev = "0b56e1c00a57fdb767674462c299a5c973a9e373";
    };
    patches = [];
  });
in {
  mpv = prev.wrapMpv mpv-git {
    # Prevent the need for prefixing mpv with DRI_PRIME=1
    extraMakeWrapperArgs = [
      "--set" "DRI_PRIME" "1"
    ];
  }; 

  gajim = prev.gajim.overrideAttrs (old: {
    # Enable notification sounds
    propagatedBuildInputs = old.propagatedBuildInputs ++ [ prev.gsound ];
  });

  animedl = prev.animedl.overrideAttrs (old: {
    extraPkgs = pkgs: with final; [ mpv ];
  });

  retroarch = prev.retroarch.override (old: {
    cores = with prev.libretro; [
      desmume
      sameboy
      mgba
      mupen64plus
      parallel-n64
    ];
  });

  libvirt = prev.libvirt.override {
    # NOTE: This to prevent libvirt from using iptables and loading
    #       ip_tables and the likes
    iptables = prev.iptables-nftables-compat;
  };

  nwg-launchers = prev.nwg-launchers.overrideAttrs (old: rec {
    version = "0.6.3";

    src = prev.fetchFromGitHub {
      owner = "nwg-piotr";
      repo = "nwg-launchers";
      rev = "v${version}";
      sha256 = "05aih05z5dybbv67qjmn90yjrk1k2l0v83hhglqqdin18k5xhq21";
    };
  });

  myxer = prev.myxer.overrideAttrs (old: {
    cargoPatches = [ ../patches/myxer/0000-1.2.1-set-gio-version.patch ];
  });

  phosh = prev.phosh.overrideAttrs (old: {
    src = prev.fetchFromGitLab {
      domain = "gitlab.gnome.org";
      group = "World";
      owner = "Phosh";
      repo = "phosh";
      rev = "v0.14.1";
      fetchSubmodules = true;
      sha256 = "sha256-FILSNVBYpWSPXeDb1Vc4jZ7zJMg0Gj6EY5yoc81gUr0=";
    };
    patches = [
      (builtins.fetchurl {
         url = "https://gitlab.gnome.org/World/Phosh/phosh/-/merge_requests/923.patch";
         sha256 = "0fad4x8hzpaf7aq6acfz90njjjrvyc9ipndxmh4kqnm03n7300x0";
       })
    ];
  });
}