nixos-config/hosts/miku.nix

{ config, lib, pkgs, ... }:

let
  mkHost = (import ../modules { lib = lib; pkgs = pkgs; }).mkHost;
in mkHost config {
  userName = "alexander";
  hostName = "miku";
  overlays = [ "nur" "steam" "unstable" "simple" "custom" "emacs" ];
  hardwareImports = [ "amdgpu" "amd" ];
  programImports = [
    "zsh" "git" "mpv" "tmux" "emacs" "firefox" "gnome-terminal" "gnome" "i18n" "gamemode"
    "distributed-build/builder.nix"
    "music"
  ];
  extraImports = [ "virtualisation/gaming.nix" "virtualisation" ];
  fileSystems = {
    "/" = {
      device = "/dev/disk/by-label/root";
      fsType = "btrfs";
    };
    "/boot" = {
      device = "/dev/disk/by-label/boot";
      fsType = "vfat";
    };
    "/mnt/Storage" = {
      device = "/dev/disk/by-label/storage";
      fsType = "ext4";
    };
  };
  extraPackages = pkgs: with pkgs; [
    emacsPgtkGcc
    gajim
    virt-manager unstable.qemu scream
    gamemode # Custom package
    key-mapper # Custom package
    replaysorcery # Custom package
    evdev-proxy # Custom package
    vfio-isolate # Custom Package
    steam
    discord-system-electron-wrapped # Custom package
    discord-wrapper # Custom package
    superpaper # Custom package
    mumble
    piper
  ];
  extraOptions = old: {
    programs.mpv.primaryScreen = "C27F398";

    # TODO: Move to virtualisation/gaming.nix
    # Allow scream to connect to this host
    networking.firewall.allowedUDPPorts = [ 4010 ];

    boot = {
      extraModprobeConfig = ''
        options kvm_amd nested=1
        options vfio-pci ids=1002:67df,1002:aaf0
      '';
      initrd = {
        availableKernelModules = [ "xhci_pci" "ahci" "usbhid" "sd_mod" "amdgpu" "vendor-reset" ];
        kernelModules = [
          "amdgpu" # GPU (duh)
          "kvm-amd" "vfio_virqfd" "vfio_pci" "vfio_iommu_type1" "vfio" # Virt
          "uinput" # key-mapper
          "vendor-reset"
        ];
      };
      kernelParams = [
        "amd_iommu=on"
        "iommu=pt"
        "sysrq_always_enabled=1"
        "kvm.ignore_msrs=1"
        "kvm.report_ignored_msrs=N"
        "fbcon=rotate:1"
        "quiet"
      ];
      extraModulePackages = [ pkgs.linuxPackages.vendor-reset ];
      # NOTE: A regression appears to have happend between 5.10 and 5.12
      #       which leads to the RX590 to have the fence fallback timer on
      #       sdma0 time out (whatever this means). Maybe bisect?
      #kernelPackages = pkgs.linuxPackages_zen;
    };
    services = {
      ratbagd.enable = true;
      flatpak.enable = true;
      # TODO: Move to hardware/ and the respective custom package
      udev.extraRules = ''
      KERNEL=="uinput", GROUP="input"

      # This rule allows the input group to access /dev/uinput device to create virtual input devices
      KERNEL=="uinput", SUBSYSTEM=="misc", GROUP="input", MODE="660"

      # Create rules for your virtual devices to get persistent names
      KERNEL=="event*", SUBSYSTEM=="input", ATTRS{name}=="EvdevProxy*", SYMLINK+="input/by-id/virtual-event-$attr{name}"
      '';
    };

    security = {
      pam.loginLimits = [
      {
        domain = "@gamemode";
        item = "-";
        type = "nice";
        value = "-10";
      }
      ];
      wrappers = {
        gamemoded = {
          source = "${pkgs.gamemode}/bin/gamemoded";
          capabilities = "cap_sys_nice+ep";
        };
      };
    };
    
    # TODO: Move into modules
    systemd.user.services = {
      scream = {
        description = "Audio receiver for the Scream virtual network sound card";
        #wantedBy = [ "default.target" ];
        serviceConfig = {
          Type = "simple";
          ExecStart = "${pkgs.scream}/bin/scream -i virbr0 -o pulse";
          Restart = "always";
        };
      };
      replaysorcery-kms = {
        description = "An open-source, instant-replay solution for Linux; KMS service";
        #wantedBy = [ "default.target" ];
        serviceConfig = {
          Type = "simple";
          ExecStart = "${pkgs.replaysorcery}/bin/replay-sorcery kms-service";
          Restart = "always";
        };
      };
      key-mapper = {
        description = "A tool to change the mapping of your input device buttons";
        wantedBy = [ "default.target" ];
        serviceConfig = {
          Type = "simple";
          ExecStart = "${pkgs.key-mapper}/bin/key-mapper-service";
          Restart = "always";
          # NOTE: The Tartarus may not be connected, so don't fail if we cannot set the preset
          ExecPostStart = "${pkgs.key-mapper}/bin/key-mapper --command start --preset NOOP --device \"Razer Razer Tartarus V2\"; exit 0";
        };
      };
      replaysorcery = {
        description = "An open-source, instant-replay solution for Linux";
        #wantedBy = [ "default.target" ];
        requires = [ "replaysorcery-kms.service" ];
        serviceConfig = {
          Type = "simple";
          ExecStart = "${pkgs.replaysorcery}/bin/replay-sorcery";
          Restart = "always";
        };
      };
      # TODO: Remove once in stable or I decide to use unstable
      gamemode = {
        description = "A daemon/lib combo for Linux that allows games to request a set of optimisations be temporarily applied to the host OS.";
        wantedBy = [ "default.target" ];
        environment.PATH = lib.mkForce (pkgs.linkFarm "pkexec" [
          {
            name = "pkexec";
            path = "${config.security.wrapperDir}/pkexec";
          }
        ]);
        serviceConfig = {
          Type = "simple";
          ExecStart = "${config.security.wrapperDir}/gamemoded";
          Restart = "always";
        };
      };
      superpaper = {
        description = "A cross-platform multi monitor wallpaper manager.";
        wantedBy = [ "default.target" ];
        path = [ pkgs.glib ];
        serviceConfig = {
          Type = "simple";
          ExecStart = "${pkgs.superpaper}/bin/superpaper";
          Restart = "always";
        };
      };
    };
  };
}